      SUBROUTINE PROPM(M,RNG1,RNG2,EGVL,EGVR,CLR,CRL,R,MX,MXT2,
     1                  IOUT)
C
C     THIS SUBROUTINE COMPUTES THE COMPLEX PROPAGATOR MATRIX R
C     CORRESPONDING TO THE INTERVAL RNG1 TO RNG2.
C       
      IMPLICIT REAL*8 (A-H,O-Z)
      COMPLEX*16 EGVL(MX),EGVR(MX),CRL(MX,MX),CLR(MX,MX)
      COMPLEX*16 R(MXT2,MXT2)
      COMPLEX*16 ONE,CI,FK1,FK2,FAC,U,V
      COMPLEX*16 CHDH,CJDJ,CDSRT
      COMPLEX*16 WJ,WH
C
      COMMON /BLKEVN/ HB,CW,CB,FKW,FKB,ROHW,ROHB,ATEN
C
      ONE=DCMPLX(1.0,0.0)
      CI=DCMPLX(0.0,1.0)
C
C
      DO 200 II=1,M
C
      FK2=FKB*CDSRT(ONE-EGVR(II))
      FAC=2.*FK2
C
      DO 100 I=1,M
C
      FK1=FKB*CDSRT(ONE-EGVL(I))
C
      U=FK2*CRL(II,I)
      V=FK1*CLR(II,I)
C
C     IOUT =  0 KEEPS U AND V DESTINCT AND GIVES THE TWO WAY SOLUTION.
C 
C     IOUT = -1 ALSO KEEPS U AND V DESTINCT BUT GIVES AN APPROXIMATION
C     TO THE SINGLE SCATTER APPROXIMATION SEE: 'THE PROBLEM OF ENERGY 
C     CONSERVATION IN ONE WAY MODELS,'BY PORTER, JENSEN AND FERLA, 
C     JASA 89, PG. 1058-1067 (1991).
C
C     IOUT =  1 EQUATES U AND V AND GIVES THE ONE WAY SOLUTION.
C
      IF(IOUT .EQ. 1) V=U
C
      WJ=CJDJ(EGVL(I),RNG1,RNG2)
      WH=CHDH(EGVL(I),RNG1,RNG2)
      R(M+II,M+I)=(U+V)*WH/FAC
      R(M+II,I)=(U-V)*WJ/FAC
      R(II,M+I)=(U-V)*WH/FAC
      R(II,I)=(U+V)*WJ/FAC
C
  100 CONTINUE
  200 CONTINUE
C
      RETURN
      END
